zappatore77, on 28 January 2024 - 01:31 PM, said:
Heliotropo, on 27 January 2024 - 09:26 PM, said:
zappatore77, on 27 January 2024 - 04:54 PM, said:
(...)
computer sleep: after 10 minutes
(...)
If you set computer sleep: never, the computer will never turn off and emule will work correctly.
Yes, I know this but on my pc I need computer sleep: after 10 minutes
Emule 0.70a on w10 and same configuration works fine ad prevent suspension mode.
So, Isn't there any other trick to fix it on w11?
Hi zappatore77
In the meantime, they investigate the issue to solve it in emule, I propose an alternative solution.
I understand that if eMule is running you want the pc not to turn off/suspend, while if it is not working it will turn off/suspend after 10 minutes.
If so, you can make two profiles (or one more). One with the power off/sleep after 10 minutes and one with the power off/sleep on never.
Then, with a script that checks if eMule is active or not, you can set either one or the other profile.
If you need help on batch script I'll help you. PS. I'm italian too!
EDIT:Since I don't know if I'll be back on this forum soon, I've prepared a sample script for you. You can optimize it so that it doesn't have to reset the profile every time, but to make you edit the script I left it very simple.
@echo off
setlocal enabledelayedexpansion
title %~n0
REM ISTRUZIONI
rem --------------
rem copiare questo codice in un file di testo e cambiare l'estensione in ".cmd"
rem mettere in avvio automatico il collegamento a questo script : windows+R shell:startup
rem per sapere la GUID delle combinazioni/profili:
rem - creare la nuova combinazione/profilo
rem - usare il comando POWERCFG -L per vedere l'elenco delle combinazioni. La combinazione attiva e' sempre contrassegnata da un asterisco "*" alla fine
rem esempio di GUID: "381b4222-f694-41f0-9685-ff5bb260df2e"
rem questo e' un ciclo infinito
for /L %%L in () do (
rem ogni 4 minuti
timeout /t 240
rem controllo se emule e' in esecuzione
set "exist_emule="
for /f "tokens=1" %%A in ('tasklist /nh /fi "imagename eq emule.exe"') do set "exist_emule=%%A"
if "!exist_emule!" equ "emule.exe" (
rem emule e' in esecuzione, setto il profilo/combinazione con sleep su "mai"
POWERCFG -S 381b4222-f694-41f0-9685-ff5bb260df2e
POWERCFG /GETACTIVESCHEME
) else (
rem emule non e' in esecuzione, setto il profilo/combinazione con sleep su 10 min
POWERCFG -S a1841308-3541-4fab-bc81-f71556f20b4a
POWERCFG /GETACTIVESCHEME
)
)
you need to edit the script and change the GUIDs that are there with your corresponding GUIDs.
This post has been edited by einstein1969new: 04 February 2024 - 10:31 PM